ダッシュボード

モニタリングスイート連携機能を用いて以下のようなダッシュボードが作成できます。

[更新: 2025年10月23日]

PromQL例

NoSQLの利用状況を監視するPromQL例を以下に示します。
※rate関数を使用しているクエリは、指定した時間範囲内での1秒あたりの平均増加率を出力します。
※それ以外のクエリは、現時点での瞬間値を取得しています。

OS / ハードウェア関連

PromQL例

・ノード別 CPU 使用率（%） 

100 * (sum by (instance) (rate(sakuracloud_nosql_node_cpu_seconds_total{mode!="idle"}[5m]))) / sum by (instance) (rate(sakuracloud_nosql_node_cpu_seconds_total[5m]))

・ノード別ディスク使用量（バイト） 

(
  sakuracloud_nosql_node_filesystem_size_bytes{mountpoint="/mnt/data", fstype="ext4"}
-
  sakuracloud_nosql_node_filesystem_avail_bytes{mountpoint="/mnt/data", fstype="ext4"}
)

・ノード別ディスク総量（バイト） 

sakuracloud_nosql_node_filesystem_size_bytes{mountpoint="/mnt/data", fstype="ext4"}

・ノード別メモリ使用量（バイト） 

(sakuracloud_nosql_node_memory_MemTotal_bytes - sakuracloud_nosql_node_memory_MemAvailable_bytes)

・ディスク読み取り速度（バイト/秒） 

rate(sakuracloud_nosql_node_disk_read_bytes_total[5m])

・ディスク書き込み速度（バイト/秒） 

rate(sakuracloud_nosql_node_disk_written_bytes_total[5m])

・ネットワーク受信速度（バイト/秒） 

rate(sakuracloud_nosql_node_network_receive_bytes_total[5m])

・ネットワーク送信速度（バイト/秒） 

rate(sakuracloud_nosql_node_network_transmit_bytes_total[5m])

JVM 関連

PromQL例

・JVM GC 時間の平均値(秒) 

rate(sakuracloud_nosql_jvm_gc_collection_seconds_sum[5m])

・JVM ヒープ領域使用量（バイト） 

sakuracloud_nosql_jvm_memory_used_bytes{area="heap"}

・JVM メモリプール使用量（バイト） 

sakuracloud_nosql_jvm_memory_pool_used_bytes

スレッドプール関連

PromQL例

・破棄された Cassandra 間メッセージ数（件/秒） 

rate(sakuracloud_nosql_cassandra_droppedmessage_dropped_count[5m])

・保留中コンパクションタスク数（件） 

sakuracloud_nosql_cassandra_compaction_pendingtasks

クライアント要求関連

PromQL例

・1秒あたりの読み取りリクエスト数（OPS） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_count{
    clientrequest=~"Read-.*"
  }[1m])
)

・1秒あたりの書き込みリクエスト数（OPS） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_count{
    clientrequest=~"Write-.*"
  }[1m])
)

・読み取りリクエスト 1 件あたり平均レイテンシ（秒） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_sum{clientrequest=~"Read.*"}[5m])
)
/
sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_count{clientrequest=~"Read.*"}[5m])
)

・書き込みリクエスト 1 件あたり平均レイテンシ（秒） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_sum{clientrequest=~"Write.*"}[5m])
)
/
sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_latency_seconds_count{clientrequest=~"Write.*"}[5m])
)

・読み取りリクエストタイムアウト件数（件/秒） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_timeouts_count{clientrequest=~"Read.*"}[5m])
)

・書き込みリクエストタイムアウト件数（件/秒） 

sum by (sakuracloud_resource) (
  rate(sakuracloud_nosql_cassandra_clientrequest_timeouts_count{clientrequest=~"Write.*"}[5m])
)